¿Que tipo de proteccion de memoria tiene el C64?

[calpirro]

Esto del Montecarlo es una tonteria

Hombre...yo no diría eso...tiene muchos campos de aplicación y es la mejor forma de encontrar solución a algunos problemas complejos. Eso sí, para calcular el PI no es mu adecuado...

[Zardoz]

Si te digo que con ese método, hicimos pruebas de paralizarlo con 3 métodos distintos el año pasado, para practicas de una asignatura, y el mejor resultado que salia con con x1000 tiradas (tus tiradas * 1000), solo coincidía en los 4 primeros decimales...

[Luna]

Para Ms-DOS hay un programa llamado "pitote" que mediante magia vudú o así va sacando buenamente decimales a punta pala de PI, algo así me gustaría tener en BASIC...

[mcleod_ideafix]

Allá va un poco de magia vudú para generar 1000 dígitos de PI en el C64:

Código: Seleccionar todo

   10 rem Programa que genera 1000 digitos de PI en el C64. (C)2013 mcleod_ideafix
   20 ntr=1000/16
   30 tam=ntr*56
   40 a=10000:b=0:c=tam:d=0:e=0:g=0
   50 dim f(tam+1)
   60 for n=1 to tam:f(n)=2000:next
   70 d=0:g=c*2
   80 if g=0 then end
   90 b=c
  100 d=d+f(b+1)*a:g=g-1:f(b+1)=d-g*int(d/g):d=int(d/g):g=g-1:b=b-1:if b then d=d*b
  105 if b then 100
  110 c=c-14:gosub 1000
  130 e=d-a*int(d/a):goto 70
 1000 nu=e+int(d/a)
 1010 n$=str$(nu)
 1015 n$=right$(n$,len(n$)-1)
 1020 print left$("0000",4-len(n$));n$;
 1030 return


El mismo programa, en un ZX Spectrum 48K

Código: Seleccionar todo

   1 REM 1000 digitos de PI en ZX Spectrum. (C)2013 mcleod_ideafix
  10 DEF FN r(a,b)=a-b*INT (a/b)
  20 LET ntram=1000/16
  30 LET tam=ntram*56
  40 LET a=10000: LET b=0: LET c=tam: LET d=0: LET e=0: LET g=0
  50 DIM f(tam+1)
  60 FOR n=1 TO tam: LET f(n)=2000: NEXT n
  70 LET d=0: LET g=c*2
  80 IF g=0 THEN STOP
  90 LET b=c
 100 LET d=d+f(b+1)*a: LET g=g-1: LET f(b+1)=FN r(d,g): LET d=INT (d/g): LET g=g-1: LET b=b-1: IF b<>0 THEN LET d=d*b: GO TO 100
 110 LET c=c-14
 120 GO SUB 1000
 130 LET e=FN r(d,a): GO TO 70
1000 REM Imprime nu con 0 a la izquierda
1005 LET nu=e+INT (d/a)
1010 LET n$=STR$ nu
1020 LET c$="0000"( TO 4-LEN n$)
1030 PRINT c$;n$;: RETURN


En cualquiera de las dos versiones, el PRINT que hay dentro del programa, imprime cada vez 4 nuevos decimales de PI. Comienza el primer bloque de 4 decimales incluyendo al 3 de la parte entera.
Si quieres más decimales, cambia en la línea 20 el valor 1000 por otro número, pero cuidando de que sea múltiplo de 16. Hay que tener en cuenta que esto usa un vector que se dimensiona de acuerdo al número de decimales que se quiere obtener, así que no podemos generar todos los decimales que queramos, sino que tenemos un límite marcado por la cantidad de elementos que puede contener un vector en BASIC.

[Luna]

He tipeado el de commodore... Ahora mi 64 está vomitando digitos de PI a buen ritmo (aunque la linea 100 la he tenido que comprimir algo para que el BASIC se la coma) nada serio, solo quitar espacios...

Ahora ansío por meter esta...cosa... en mi TurboR a ver cuantos saca con el r800...

[marcos64]

Allá va un poco de magia vudú para generar 1000 dígitos de PI en el C64:

Código: Seleccionar todo

   10 rem Programa que genera 1000 digitos de PI en el C64. (C)2013 mcleod_ideafix
   20 ntr=1000/16
   30 tam=ntr*56
   40 a=10000:b=0:c=tam:d=0:e=0:g=0
   50 dim f(tam+1)
   60 for n=1 to tam:f(n)=2000:next
   70 d=0:g=c*2
   80 if g=0 then end
   90 b=c
  100 d=d+f(b+1)*a:g=g-1:f(b+1)=d-g*int(d/g):d=int(d/g):g=g-1:b=b-1:if b then d=d*b
  105 if b then 100
  110 c=c-14:gosub 1000
  130 e=d-a*int(d/a):goto 70
 1000 nu=e+int(d/a)
 1010 n$=str$(nu)
 1015 n$=right$(n$,len(n$)-1)
 1020 print left$("0000",4-len(n$));n$;
 1030 return


Como era facil de suponer, tambien funciona en un C16. Eso si, lo he probado con 64KB.

[mcleod_ideafix]

Y ya que os poneis... mirad este proyecto: el PIfs : un sistema de ficheros basado en el número PI.
https://github.com/philipl/pifs

La idea es tan simple como bizarra: resulta que el número PI, que como todos sabemos tiene infinitos decimales y no es periódico, tiene varias propiedades, entre ellas, que alberga todas las posibles combinaciones de valores.
Eso quiere decir que un fichero que hayas creado, que no es más que una sucesión de bytes, EXISTE en algún punto dentro del número PI.
Así que en lugar de almacenar el fichero completo, basta con almacenar su posición dentro de PI.

[Luna]

Y ya que os poneis... mirad este proyecto: el PIfs : un sistema de ficheros basado en el número PI.
https://github.com/philipl/pifs

La idea es tan simple como bizarra: resulta que el número PI, que como todos sabemos tiene infinitos decimales y no es periódico, tiene varias propiedades, entre ellas, que alberga todas las posibles combinaciones de valores.
Eso quiere decir que un fichero que hayas creado, que no es más que una sucesión de bytes, EXISTE en algún punto dentro del número PI.
Así que en lugar de almacenar el fichero completo, basta con almacenar su posición dentro de PI.

ya, una vez busqué y encontre mi numero de telefono en los decimales de PI, eso significa que en algún lado tendría que haber no see... Un rip de la pelicula metropolis de fritz lang, pero con carteles en escandinavo, escritos en "comic sans" y banda sonora de las Spice Girls interpretando canciones de Los Panchos con eructos y subtitulos con los escritos del mar muerto?

[mcleod_ideafix]

eso significa que en algún lado tendría que haber no see... Un rip de la pelicula metropolis de fritz lang, pero con carteles en escandinavo, escritos en "comic sans" y banda sonora de las Spice Girls interpretando canciones de Los Panchos con eructos y subtitulos con los escritos del mar muerto?

Exacto.
Otra cosa es que el universo exista el suficiente tiempo como para que lo encuentres.

[zup]

ya, una vez busqué y encontre mi numero de telefono en los decimales de PI, eso significa que en algún lado tendría que haber no see... Un rip de la pelicula metropolis de fritz lang, pero con carteles en escandinavo, escritos en "comic sans" y banda sonora de las Spice Girls interpretando canciones de Los Panchos con eructos y subtitulos con los escritos del mar muerto?

Eso sería un interesante argumento a favor de la piratería... dado que:

- Pi es una constante universal, y dudo mucho que se pueda registrar para tener derechos de autor.
- Cualquier secuencia imaginable de números está dentro de Pi (¿hay algún tipo de demostración matemática o eso es un postulado? ¿se aplica solo a Pi o vale para otras constantes del palo tipo e).

Podríamos copiar cualquier tipo de contenido ya que, a fin de cuentas, los derechos de autor no serían válidos (estarían intentando registrar porciones de algo que no han escrito). Ahora se lo contamos a la SGAE a ver si les explota la cabeza.