Número aleatorio 0-100 en Z80

[Namek]

llevo años sin tocar basic, pero ahora se me ha ocurrido este bugfix, o si no, caray, quien no se acuerda de sacar numeros aleatorios en BASIC?

No me hagas mucho caso pero me parece que la referencia del titulo del hilo "Z80" se refiere a ensamblador del Z80... aunque puede que este equivocado...

[explorer]

Pues sí, Namek, se trata de ensamblador. Y la solución no parece muy evidente.

[jltursan]

Prueba con esta:

Código: Seleccionar todo

ld hl,(seed)
ld a,r
ld d,a
ld e,(hl)
add hl,de
add a,l
xor h
ld (seed),hl
ld h,0
ld l,a
add hl,hl
add hl,hl
ld b,h
ld c,l
add hl,hl
add hl,hl
add hl,hl
ld d,h
ld e,l
add hl,hl
add hl,de
add hl,bc
ld a,h
ret
seed:    dw 0

Te devuelve en A el valor que buscas entre 0-99 (que no 100, no se si eso altera mucho el asunto). Pruebala no sea que haya metido la pata en alguna "tontá"

[explorer]

No habría estado demás que el código estuviese "comentado", con sus puntos y comas

[jltursan]

No habría estado demás que el código estuviese "comentado", con sus puntos y comas

Salió en un arreón

La versión en cristiano:

Código: Seleccionar todo

; Rutina para obtener un pseudoaleatorio entre 0-255 en A
; La semilla inicial es 0
ld hl,(seed)
ld a,r
ld d,a
ld e,(hl)
add hl,de
add a,l
xor h
; Guardamos una nueva semilla para aumentar la aleatoriedad la siguiente invocacion
ld (seed),hl
; y almacenamos en HL el valor aleatorio obtenido
ld h,0
ld l,a
; Multiplicamos ese valor por 100
add hl,hl
add hl,hl
ld b,h
ld c,l
add hl,hl
add hl,hl
add hl,hl
ld d,h
ld e,l
add hl,hl
add hl,de
add hl,bc
; Dividimos por 256 y al tiempo almacenamos en A el valor 0-99
ld a,h
ret
seed:    dw 0

La rutina de obtención de un aleatorio 0-255 no necesita explicación, vale cualquiera de las que pululan por ahí. Lo único que se hace a continuación es multiplicar por 100 y dividir por 256, de esa manera obtenemos el equivalente de haber calculado un aleatorio entre 0 y 1 y haberlo multiplicado por 100.

[explorer]

De acuerdo, se trata entonces de hacer

Código: Seleccionar todo

RND()*100 =
RND()*100 * 256/256 =
RND()*256 * 100/256

valor = RND()*256 se obtiene por medio del generador y la semilla. Queda

Código: Seleccionar todo

valor * 100 / 256 =
(valor*4 + valor*32 + valor*64) / 256 =
byte_alto(valor*4 + valor*32 + valor*64)

El detalle que faltaría, para que fuera exactamente en el rango 0-100, es sumar una vez más el acumulador a hl antes de sacar el byte alto.

[jltursan]

Efectivamente, añadiendo A:

Código: Seleccionar todo

; Rutina para obtener un pseudoaleatorio entre 0-255 en A
; La semilla inicial es 0
ld hl,(seed)
ld a,r
ld d,a
ld e,(hl)
add hl,de
add a,l
xor h
; Guardamos una nueva semilla para aumentar la aleatoriedad la siguiente invocacion
ld (seed),hl
; y almacenamos en HL el valor aleatorio obtenido
ld h,0
ld l,a
; Multiplicamos ese valor por 101
add hl,hl
add hl,hl
ld b,h
ld c,l
add hl,hl
add hl,hl
add hl,hl
ld d,h
ld e,l
add hl,hl
add hl,de
add hl,bc
add a,l
ld l,a
adc a,h
sub l
; En A ya nos queda el valor dividido por 256 entre 0-100
ret
seed:    dw 0

Ya tenemos el rango 0-100 listo

A ver si Uto nos cuenta que tiene entre manos. Viendo el rango no creo que se trate de un analizador de los resultados de la primitiva...

[Lord Raptor]

Puedes usar el registro R para obtener números aleatorios.

[Namek]

Puedes usar el registro R para obtener números aleatorios.

Si, usando por ejemplo un "LD A,R" como se puede ver en el código de ejemplo que hay en el mensaje justo anterior al tuyo...

[mcleod_ideafix]

Puedes usar el registro R para obtener números aleatorios.

Para inicializar una semilla de un generador de números aleatorios te puede valer, pero para sacar de forma sistemática números aleatorios es menos eficiente, ya que la secuencia que te saldría sería monotónica, o sea, muy lejos de ser considerada aleatoria.