- doble_pantalla.gif (25.97 KiB) Visto 16453 veces
EL JUEGO
Este videojuego arcade fue desarrollado por Taito en 1979.
El objetivo del juego consiste en rescatar a los hombrecitos que están en la superficie del planeta controlando un módulo de aterrizaje. Primero hay que desengancharse de la nave nodriza, sortear el cinturón de asteroides durante el descenso y alunizar en las plataformas. Durante el ascenso deberemos sortear o destruir las naves enemigas y volver a ensamblar en la nave nodriza.
Controles:
Pulsa Z o X para mover el módulo de aterrizaje a izquierda o derecha.
Pulsa la barra espaciadora para desengancharte, frenar o disparar.
Obtenemos puntos por aterrizar en las plataformas y destruir las naves enemigas.
Al finalizar el nivel recibimos puntos por cada hombre rescatado y un bonus de 500 puntos si los rescatamos todos.
Descargar el juego en formato ".D64":
BLOQUES
Se ha dividido el listado en 13 bloques:
- Declaración de las matrices. Llamada a rutinas principales.
- Controlar los distintos movimientos de nuestra nave.
- Control de los invasores y asteroides.
- Detección de las colisiones de nuestra nave. Toca suelo, asteroide, nave enemiga, nave nodriza o estrellas.
- Perder una vida.
- La nave aluniza en una plataforma.
- La nave se ensambla a la nave nodriza.
- Pantalla de Presentación.
- Inicio de la partida.
- Rutinas varias.
- DATA con rutina en código máquina que duplica el juego de caracteres en otra posición.
- DATA con los gráficos del juego.
- DATA con los datos de los enemigos y la posición y tipos de plataformas de aterrizaje.
COMO FUNCIONA
Todo el programa ocupa 142 líneas.
A continuación indico el principio de las distintas partes del programa:
10 - Definimos las matrices del juego.
30 – Saltar a la rutina que redefine los gráficos.
50 – Vamos a la presentación del juego.
100 – Si la nave esta enganchada (T=0) salta a 180.
110 – Leer el teclado y mover nuestra nave en descenso o ascenso.
130 – Control de la nave durante el descenso (T=1).
150 – Control de la nave durante el ascenso (T=2).
160 – Control de nuestro disparo durante el ascenso.
180 – Movimiento de la nave nodriza si estamos enganchados (T=0).
200 – Movemos una de las 5 filas de asteroides o naves enemigas en la dirección correspondiente.
230 – Revisamos si hay algo encima de nuestra nave. Si hay salta a 500.
400 – Si la posición Y está en la zona de los asteroides o naves enemigas salta a 500.
410 – Si es estamos descendiendo mira que hay a los pies de nuestra nave. Salta a 600 si hay una plataforma.
420 – Si estamos ascendiendo mira si encajamos con la zona central de la nave nodriza. Salta a 700 si nos enganchamos.
450 – Si nuestro disparo toca una nave enemiga ponemos la explosión, sumamos puntos y la hacemos desaparecer.
500 – Ponemos una explosión en la posición de nuestra nave y reproducimos un sonido.
505 – Miramos si hemos colisionado con la nave nodriza y hacemos la animación del hombrecito cayendo.
520 – Actualizamos el marcador de vidas, y si hay más hombres a rescatar seguimos la partida.
550 – Si no hay más vidas finaliza la partida.
600 – La nave a alunizado sobre una plataforma. Calculamos en que plataforma lo hemos hecho.
625 – Borramos uno de los hombrecitos de la superficie del planeta, y sumamos y mostramos los puntos.
630 – Activamos el ascenso, contador de hombres pendientes de rescatar y borramos la plataforma de aterrizaje.
700 – La nave ha ensamblado con la nave nodriza. Actualizamos hombres rescatados y lo ponemos en la parte superior.
720 – Si hay más hombres a rescatar (HP) la partida sigue.
730 – Si hemos rescatado los 6 hombres recibimos 500 puntos de bonificación.
750 – Recibimos puntos por cada hombre rescatado.
780 – Incrementamos el nivel de dificultad.
2000 – Pantalla de presentación del juego.
2050 – Al pulsar una tecla borramos la pantalla (5400) y actualizamos el marcador del jugador 1.
2180 – Mostramos el mensaje de puntos por hombre rescatado.
2190 – Inicialización de las variables principales de la partida.
2200 – Mostrar la zona de juego.
2580 – Inicializar parte de las variables del juego.
5000 – Rutina para redefinir el juego de caracteres. Aquí se baja el RAMTOP 1KB.
5010 – Se carga la rutina en ensamblador desde los DATA en memoria y se ejecuta.
5020 – Copiamos los DATA de los gráficos en la nueva posición y cambiamos los colores de pantalla.
5050 – Guardamos en una matriz las posiciones de los hombres en la superficie del planeta.
5060 – Guardamos en una matriz las posiciones de las plataformas de aterrizaje.
5100 – Rutina que activa el juego de caracteres redefinido.
5200 – Rutina que activa el juego de caracteres original. El nuestro queda residente en memoria.
5300 – Rutina que activa los colores por defecto del C-16 cuando está en BASIC.
5400 – Rutina de borrado de pantalla.
5500 – Rutina de PAUSA. Valor en (J).
5600 – Rutina que muestra las 5 filas de enemigos (según corresponde) en su posición y con el color correspondiente.
5700 – Rutina que genera las tiras de los enemigos en una matriz de dos dimensiones (E).
5800 - Rutina para vaciar el buffer del teclado.
8000 – Valores DATA de la rutina en código máquina que duplica el juego de caracteres en otra posición de memoria.
9000 – Línea DATA con los gráficos del juego.
9500 – DATA con los gráficos de los 5 enemigos distintos (2 asteroides y 3 naves).
9510 – Posición de los distintos hombrecitos.
9520 – Posición y gráficos de las distintas plataformas de aterrizaje.
EL LISTADO
Código: Seleccionar todo
10 DIME$(2,5),V(5),C$(5),G$(5),BX(6),BY(6),BE(6),BG$(6),HX(6),HY(6),HE(6)
30 GOTO5000
50 GOSUB2000
' Control de la nave
100 IFT=0THEN180
110 GETK$:X1=X
115 IFK$="Z"THENIFX>5ANDY>5THENX=X-1:M=M-1
120 IFK$="X"THENIFX<34ANDY>5THENX=X+1:M=M+1
125 IFT=2THEN150:ELSESOUND3,500,11
' Descenso de la nave
130 IFK$=CHR$(13)THENIFC>0THENC=C-10:CHAR1,10,3," ":PRINTUSING"###";C:GOTO175
140 CHAR1,X1,Y,"œ ":Y=Y+1:M=M+40:IFPEEK(M+40)+PEEK(M+41)<>64THEN400:ELSE175
' Ascenso de la nave
150 SOUND3,800,12:CHAR1,X1,Y,"œ "
155 K=-K:IFK=1THENY=Y-1:M=M-40:IFPEEK(M)+PEEK(M+1)<>64THEN400
' Control del disparo de la nave
160 IFS>0THEN165
162 IFK$=CHR$(13)THENS=M:K=1:ELSE175
165 IFPEEK(S)=73THENPOKES,32
170 S=S-40:IFS<3232THENS=0:GOTO175:ELSEIFPEEK(S)<>32THEN450
175 POKES,73:CHAR1,X,Y,"œ²³ ´µ":GOTO200
' La nave esta ensamblada
180 XN=XN+D:IFXN<4ORXN>31THEND=-D
185 CHAR1,XN-1,4,"œ ¤¥®¯¨© ":CHAR1,XN-1,5," ª«°± "
190 U=U-1:GETK$:IFK$=CHR$(13)THENU=0
195 IFU=0THENX=XN+2:Y=5:T=1:K=1:M=3072+Y*40+X:CHAR1,X,4,"œ¦§ ²³ ´µ"
' Control de los enemigos
200 IFB=1THENE$(E,A)=RIGHT$(E$(E,A),1)+LEFT$(E$(E,A),33):GOTO220
210 E$(E,A)=RIGHT$(E$(E,A),33)+LEFT$(E$(E,A),1)
220 CHAR1,3,V(A),C$(A)+E$(E,A):IFA<5THENA=A+1:B=-B:ELSEA=1:B=1
' ¿La nave colisiona con un enemigo?
225 IFT=0THEN100
230 F=PEEK(M)+PEEK(M+1):IFF<>64ANDF<>229THEN500
235 F=PEEK(M+40)+PEEK(M+41):IFF<>64ANDF<>233THEN500
240 GOTO100
' Rutina de detección de colisión
400 IFY>4ANDY<18THEN500
410 IFT=1THENF=PEEK(M+40):I=PEEK(M+41):IFF>85ANDF<98ANDI>85ANDI<98THEN600
415 IFT=2THENF=PEEK(M)+PEEK(M+1):IFF=205THEN700
420 GOTO500
' Destruir una nave enemiga
450 J=PEEK(S):IFJ<67ORJ>72THEN475
455 F=INT((S-3072)/40):I=S-3072-F*40:IFJ=68ORJ=70ORJ=72THENI=I-1
460 SOUND3,400,15:CHAR1,I,F,"¸¹":IFJ>70THENP=P+50:ELSEP=P+30
470 GOSUB5900:F=(F-5)/2:E$(2,F)=LEFT$(E$(2,F),I-3)+" "+MID$(E$(2,F),I):A=F
475 S=0:GOTO175
' Perdemos una vida / Final de partida
500 CHAR1,X,Y,"œ¸¹ ¸¹":FORF=500TO100STEP-25:SOUND3,F,2:NEXT:IFS>0THENPOKES,32
505 IFY<7ANDT=2THENCHAR1,31,6,"AAA...":GOSUB580:CHAR1,31,6," "
510 GOSUB5500:CHAR1,X,Y," ":IFL=1THEN550:ELSEL=L-1
520 GOSUB2200:CHAR1,L*2+4,24," ":IFHP>0THEN100:ELSE730
550 CHAR1,15,10,"ŸGAME OVER":J=3000:GOSUB 5500:IFR<PTHENR=P
560 GOTO50
' Animación de caida del hombre rescatado
580 J=100:I=M+80:FORF=Y+2TO19:POKEI,124:GOSUB5500:POKEI,32:I=I+40:NEXT:RETURN
' La nave aterriza en una plataforma
600 Y=Y-1:M=M-40:CHAR1,X,Y,"²³ ´µ"
605 IFY=18THENF=17:I=5:P=P+50:J=1
610 IFY=19ANDX>17THENF=18:I=4:P=P+100:J=3:GOTO625
615 IFY=19ANDX>6THENF=7:I=4:P=P+100:J=2
620 IFY=20THENF=X:I=2:P=P+150:J=(X-8)/11+4
625 BE(J)=0:CHAR1,HX(HP),HY(HP)," ":J=800:GOSUB5500:GOSUB5900
630 T=2:K=1:E=2:HE(HP)=0:HP=HP-1:GOSUB5600:J=800:GOSUB5500:CHAR1,F,Y+2,LEFT$(" ",I)
640 GOSUB5800:GOTO100
' La nave ensambla con la nave nodriza / Pasar nivel
700 CHAR1,XN+2,4,"œ®¯ °±":T=0:U=120:J=800:GOSUB5500:HR=HR+1:CHAR1,34-HR*2,3," ¢"
720 IFHP>0THENE=1:GOSUB5600:GOSUB5500:GOSUB5800:GOTO100
730 IFHR<6THEN740:ELSECHAR1,12,8,"BONUS 500 POINTS":J=1500:GOSUB5500
740 P=P+500:GOSUB5900:CHAR1,12,8," ":J=1000:GOSUB5500
750 FORHR=HRTO1STEP-1:CHAR1,34-HR*2,3," ":P=P+O*50:GOSUB5900:J=250:GOSUB5500:NEXT
760 O=O+1:J=1000:GOSUB5500:GOSUB5400:GOSUB2170:GOTO100
' Pantalla de presentación
2000 SCNCLR:GOSUB5800:CHAR1,4,0,"ŸSCORE-1 SCAINET žSCORE-2"
2005 GOSUB5900:CHAR 1,17,1,"":J=R:GOSUB5910
2010 CHAR1,26,24,"œCREDIT Ÿ0":CHAR1,9,5,"œ*** LUNAR RESCUE ***"
2020 CHAR1,13,11,"Ÿº º º º º º º"
2030 CHAR1,18,17,"ž1979":CHAR1,10,19," » TAITO CORPORATION"
2050 GETKEYA$:CHAR1,6,24,"Ÿ··":CHAR1,5,1,"Ÿ00000":O=1:L=3:P=0
2170 GOSUB5400:CHAR1,13,11,"ŸPLAY PLAYER<1>"
' Pantalla que indica los puntos por hombre rescatado
2180 CHAR1,14,13,"Ϣ=":PRINTUSING"### POINTS";O*50:J=1500:GOSUB5500:GOSUB5400
' Mostrar la zona de juego
2190 XN=17:D=.5:HP=6:HR=0:FORF=1TO6:BE(F)=1:HE(F)=1:NEXT:GOSUB5700
2200 CHAR 1,4,2,"ŸË Ë Ë Ë Ë Ë Ë Ë Ë Ë Ë Ëž Ë Ë Ë Ë Ë":CHAR1,5,3," FUEL 800"
2210 CHAR1,3,18," Î":CHAR1,3,19,"Ï":CHAR1,36,18,"Ò":CHAR1,36,19,"Ó"
2220 CHAR 1,3,20,"Ð":PRINTTAB(36);"Ô"
2230 CHAR 1,3,21,"ŸÐÑ":PRINTTAB(35);"ÕÔ" "
2240 CHAR 1,3,22,"ÐÐÑ ÌÌÌÌÌÌÌÌÌÌÌÌÌÌÌÌÌÌÌÌÌÌÌÌÌÌ ÕÔÔ"
2250 CHAR 1,3,23," ":PRINTUSING"ÖÖÖÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÖ#Ö";O
2260 CHAR1,5,10,"ŸÊ":CHAR1,31,12,"œÊ":CHAR1,25,18,"žÊ"
2270 FOR F=1TO6
2280 IFF=1ORF=6THENA$=" ":ELSEA$="Ÿ"
2290 IFHE(F)=1THENCHAR1,HX(F),HY(F),A$+"¢"
2295 IFBE(F)=1THENCHAR1,BX(F),BY(F),BG$(F)
2300 NEXT
' Reiniciar las variables del juego
2580 A=1:B=1:X=19:Y=4:T=0:E=1:Q=8:C=800:S=0:U=120:GOSUB5600:GOSUB5800
2590 RETURN
' RUTINA: Redefinir los UDG e inicializar matrices
5000 POKE56,59:POKE52,59:CLR
5010 FORA=1536TO1570:READB:POKEA,B:NEXT:SYS1536
5020 FORF=15880TO16359:READB:POKEF,B:NEXT:GOSUB5100
5030 COLOR0,1:COLOR1,2:COLOR4,1:VOL8:TRAP5300
5040 R=2013:A$="Ÿœž ":FORF=1TO5:C$(F)=MID$(A$,F,1):READG$(F):V(F)=5+2*F:NEXT
5050 FORF=1TO6:READHX(F),HY(F):NEXT
5060 FORF=1TO6:READBY(F),BX(F),BG$(F):NEXT
5070 GOTO50
' RUTINA: Habilitar los UDG definidos
5100 PRINTCHR$(8):POKE 65299,60:POKE 65298,PEEK(65298)AND251:RETURN
' RUTINA: Deshabilitar los UDG definidos
5200 POKE65299,208:POKE65298,PEEK(65298)OR4:RETURN
' RUTINA: Volver al BASIC y restablecer los colores
5300 GOSUB5200:COLOR0,2:COLOR1,1:COLOR4,7:SCNCLR:PRINTERR$(ER),EL:END
' RUTINA: Borrar parte de la pantalla
5400 FORF=3TO23:CHAR1,2,F," ":NEXT:RETURN
' RUTINA: Pausa. Valor en "J".
5500 FORFF=0TOJ:NEXT:RETURN
' RUTINA: Reimprimir la tira de enemigos
5600 FORFF=1TO5:CHAR1,3,V(FF),C$(FF)+E$(E,FF):NEXT:RETURN
' RUTINA: Generar las filas de enemigos
5700 IFO>5THENJ=5:ELSEJ=O
5710 FORF=1TO2:FORI=1TO5
5715 E$(F,I)=""
5720 IFF=1THENN=INT(RND(1)*2)+1:ELSEN=INT(RND(1)*3)+3
5730 E$(F,I)=E$(F,I)+G$(N)+LEFT$(" ",RND(1)*6+(8-J))
5740 IFLEN(E$(F,I))<28THEN5720
5750 E$(F,I)=LEFT$(E$(F,I)+" ",34)
5760 NEXTI,F
5770 RETURN
' RUTINA: Rutina de vaciado del buffer del teclado
5800 GETK$:IFK$<>""THEN5800:ELSERETURN
' RUTINA: Imprimir el marcador en formato "00000"
5900 CHAR1,5,1,"Ÿ":J=P
5910 A$=RIGHT$("0000"+MID$(STR$(J),2),5):PRINTA$:RETURN
' RUTINA: Código de la rutina ensamblador para redefinir los UDG
8000 DATA 169,0,133,208,169,208,133,209,169,0,133,210,169,60,133,211,162,4,160
8010 DATA 0,177,208,145,210,200,208,249,230,209,230,211,202,208,240,96
' RUTINA: Gráficos del juego
9000 DATA 0,20,42,193,65,69,58,0,0,0,24,38,65,50,12,0
9010 DATA 7,1,15,63,246,63,31,12,224,128,240,252,111,252,248,48
9020 DATA 1,15,15,26,127,28,8,0,0,224,224,176,252,56,16,0
9030 DATA 7,1,3,15,26,31,12,0,192,0,128,224,176,240,96,0
9040 DATA 0,0,3,3,3,3,0,0,0,0,8,28,8,0,0,0,0,16,40,84,40,0,0,0
9050 DATA 0,0,0,0,16,48,49,123,178,251,255,255,255,255,255,255
9060 DATA 128,128,128,192,192,192,224,240,240,248,248,188,252,220,222,254
9070 DATA 174,246,215,255,255,215,223,251,254,255,223,191,222,92,254,255
9080 DATA 1,1,1,3,3,3,7,15,15,31,31,61,63,59,123,127
9090 DATA 117,111,235,255,255,235,251,223,127,255,243,253,123,58,127,255
9100 DATA 255,255,255,255,255,255,255,255,255,127,44,45,108,111,236,255
9110 DATA 255,255,70,214,84,84,70,255
9120 DATA 255,255,63,255,127,31,63,7,255,255,255,236,237,237,237,236
9130 DATA 255,255,255,99,107,107,107,99,254,252,248,248,252,224,240,128
9140 DATA 255,127,31,127,63,15,31,1,255,255,255,252,253,252,255,252
9150 DATA 255,255,255,99,235,107,107,99,0,0,0,0,0,0,0,0,255,255,255,254,254,255,252,254
9160 DATA 0,28,28,73,62,28,20,54,0,0,0,0,0,0,0,0
9170 DATA 0,15,0,0,3,15,31,63,0,252,32,252,255,255,51,255
9180 DATA 3,31,63,255,224,128,0,0,192,248,252,255,7,1,0,0
9190 DATA 0,63,4,63,255,255,204,255,0,240,0,0,192,240,248,252
9200 DATA 63,31,15,3,0,0,0,0,255,255,255,255,255,63,15,7
9210 DATA 255,255,255,255,255,252,240,224,252,248,240,192,0,0,0,0
9220 DATA 3,31,63,255,225,143,31,58,192,248,252,255,135,241,248,92
9230 DATA 31,15,15,21,21,17,56,255,248,240,240,168,168,136,28,255
9240 DATA 0,0,0,0,0,1,15,31,0,0,0,0,0,128,240,248
9250 DATA 58,31,15,15,21,21,17,56,92,248,240,240,168,168,136,28
9260 DATA 1,15,58,31,15,53,37,96,128,240,92,248,240,172,164,6
9270 DATA 130,8,35,7,139,28,8,67,80,2,104,225,216,232,145,4
9280 DATA 60,126,219,255,102,60,66,36,60,66,153,161,161,153,66,60
9290 DATA 99,20,28,252,62,9,29,28
' RUTINA: Datos de los enemigos y posición de plataformas y hombrecitos
9500 DATA "Á","Â","ÃÄ","ÅÆ","ÇÈ"
9510 DATA 35,20,34,21,33,22,6,22,5,21,4,20
9520 DATA 20,17," ÝÖÿß¡",21,7,"ŸÙÚÛÜ",21,18,"ŸÙÚÛÜ",22,8,"Ÿ×Ø",22,19,"Ÿ×Ø",22,30,"Ÿ×Ø"
Nota:
He listado el programa desde el emulador VICE y ha perdido los caracteres especiales. Sorry.
APUNTES FINALES
A principios de los 90 programé en ensamblador con un MSX una versión más simple de este juego, y llevaba tiempo deseando hacer una versión más completa y fiel al original.
Como tenía fresca la programación del C-16 y había sido una experiencia satisfactoria, me decidí a hacer una versión con el Commodore Plus/4.
Principales descartes respecto al original:
- Esta versión es un poco más ancha y menos alta porque el formato del original es vertical.
- Hay algunas filas de asteroides y naves menos debido al tema del tamaño.
- Durante el descenso no frenamos la nave. La paramos completamente mientras hay fuel.
- Durante el ascenso no podemos acelerar.§ Los invasores no disparan y no se aceleran al avanzar en el juego.
- La nave nodriza no se mueve cuando descendemos o ascendemos.
- No aparecen las bolas de fuego que cruzan la pantalla durante el ascenso.
Por el resto, el juego tiene un aspecto y una mecánica casi idéntica al original.
El programa no es todo lo rápido que me gustaría pero se deja jugar perfectamente y es difícil. El programa es más complejo y largo que otros realizados previamente.
Para redefinir los gráficos he usado la misma rutina que con el “Galaxy Wars”, pero aquí hay muchos más gráficos.
El control de los enemigos es muy simple. Hay 5 tiras con los enemigos en su posición correspondiente. Las filas pares rotan a la izquierda y las impares a la derecha. Con LEFT$ y RIGHT$ muevo un carácter de un extremo al otro e imprimo la fila con el color correspondiente. Todo muy rápido y sencillo gracias al comando CHAR. Estas tiras están almacenadas en una matriz de dos dimensiones. El primer índice marca la tira a visualizar según descendamos o ascendamos.
El control de colisiones es más completo y complejo. Para detectarlas accedo directamente a la zona de memoria reservada al video. Hay 1 KB para los caracteres y otro para los atributos de color.
Durante el ascenso he reducido la velocidad a la mitad del descenso para facilitar la destrucción de naves enemigas.
He tenido que guardar el estado de las plataformas y los hombrecitos en unas matrices ya que al colisionar podemos borrar parte del escenario y al redibujarlo perdía el estado.
He respetado las puntuaciones y bonus del original, y he incluido la caída del hombrecito al chocar con nuestra nave nodriza durante el ascenso.
Respecto al equipo
Este es mi primer programa con un Plus/4 y la verdad es que es prácticamente igual al C-16. La única pega que he encontrado ha sido el tamaño y forma de las teclas de los cursores. Pequeñas y poco cómodas.
Para poder pasar el programa al PC he usado una placa 1541-III. Como el conector del casete es distinto la he tenido que alimentar con una fuente de alimentación de 5V externa. En el emulador de PC funciona “casi” exactamente igual. He aprovechado para retocar algún gráfico que en la TV no se apreciaba que tuviera algún pequeño fallo.
Respecto al BASIC es bastante completo y rápido. Adaptaré el juego a otros sistemas pero dudo que tengan tan buen rendimiento.
Pues nada más, solo me queda esperar que os guste.
Os invito a probarlo.
- DSC_1145.jpg (119.19 KiB) Visto 16453 veces
- LunarRescue_1.gif (3.49 KiB) Visto 16453 veces
- LunarRescue_2.gif (2.91 KiB) Visto 16453 veces
- LunarRescue_3.gif (5.75 KiB) Visto 16453 veces
- LunarRescue_4.gif (5.8 KiB) Visto 16453 veces
- LunarRescue_5.gif (5.76 KiB) Visto 16453 veces
- LunarRescue_6.gif (5.99 KiB) Visto 16453 veces
- LunarRescue_7.gif (5.49 KiB) Visto 16453 veces
- LunarRescue_8.gif (5.85 KiB) Visto 16453 veces
¡Genial Dani! 
